extends Node3D
class_name TowerManager


enum STATE { IDLE, PLACING }
var _state : int = STATE.IDLE


@onready var cam : Camera3D = $"../Camera3D"
@onready var selection_icon : Sprite3D = $Sprite3DSelection


var towers : Dictionary
var selected_collider : CollisionObject3D
var selected_tower : Tower = null
var the_cube : TheCube


func _ready() -> void:
	EventBus.tower_selected.connect(selectTower)
	EventBus.cube_ready.connect(func(value): the_cube = value)
	#$AnimationPlayer.play("arrow_bobbing")

func _process(_delta: float) -> void:
	handle_player_controls()
	if Input.is_action_just_pressed("build"):
		if not selected_collider:
			return

		if selected_collider is Tower && selected_collider != selected_tower:
			EventBus.tower_selected.emit(selected_collider.tower_type)
		elif selected_collider.collision_layer == 1:
			build_tower()

	if Input.is_action_just_pressed("rest"):
		if _state == STATE.PLACING:
			quit_placing()

		if selected_collider is Tower:
			selected_collider.is_rest = true
			selected_collider.global_position = Vector3.ZERO
			emitTeamChanges()

func handle_player_controls() -> void:
	var space_state : PhysicsDirectSpaceState3D = get_world_3d().direct_space_state
	var mouse_pos : Vector2 = get_viewport().get_mouse_position()

	var origin : Vector3 = cam.project_ray_origin(mouse_pos)
	var end : Vector3 = origin + cam.project_ray_normal(mouse_pos) * 100
	var ray : PhysicsRayQueryParameters3D = PhysicsRayQueryParameters3D.create(origin, end)
	ray.collide_with_bodies = true

	var ray_result : Dictionary = space_state.intersect_ray(ray)

	if ray_result.is_empty():
		visible = false
		selected_collider = null
		return

	selected_collider = ray_result.get("collider")
	visible = true
	selection_icon.visible = true
	global_position = selected_collider.global_position
	global_position += Vector3(0.0,0.02,0.0)

	if _state == STATE.PLACING:
		selected_tower.sprite.modulate = "ff4545c8" #If the tower can't be placed he is red
		selection_icon.visible = false
		if selected_collider is BuildTile: #if we are placing a tower, hide the selector model
			selected_tower.sprite.modulate = "61ff45c8" #If the tower can be placed he is green


func quit_placing() -> void:
	_state = STATE.IDLE

# Refactoriser ce code
func build_tower() -> void:
	if !visible || !selected_tower:
		return

	if not selected_tower.builded && selected_tower.price > the_cube.money:
		#Can't build
		print("Too costly")
		return

	if selected_tower.is_rest:
		if not selected_tower.builded:
			#Build Tower
			selected_tower.build()
			remove_child(selected_tower)
			$"../Towers".add_child(selected_tower)
			quit_placing()
		selected_tower.is_rest = false

	selected_tower.global_position = global_position
	emitTeamChanges()


func selectTower(towerType: Tower.TYPE):
	# Hide current not builded tower
	if selected_tower && not selected_tower.builded:
		selected_tower.visible = false

	_state = STATE.IDLE
	if selected_tower && selected_tower.tower_type == towerType || towerType == Tower.TYPE.NONE:
		selected_tower = null
	elif towers.has(towerType):
		selected_tower = towers.get(towerType)
		selected_tower.visible = true
	else:
		_state = STATE.PLACING
		selected_tower = Game.towers.get(towerType).instantiate()
		towers.set(towerType, selected_tower)
		selected_tower.collision_layer = 0
		add_child(selected_tower)


func emitTeamChanges() -> void:
	var team_in_action : int = 0
	var team_in_rest : int = 0
	var tower_count : int = 0
	for towerType in towers:
		var tower : Tower = towers[towerType]
		if tower.builded:
			tower_count += 1
			if tower.is_rest:
				team_in_rest += 1
			else:
				team_in_action += 1

	EventBus.team_in_action_changed.emit(team_in_action)
	EventBus.team_in_rest_changed.emit(team_in_rest)
	EventBus.tower_count_changed.emit(tower_count)