@tool
extends Control

const BUTTON_QTY = 4

const guiButton : PackedScene = preload("res://UI/gui_button.tscn")

@onready var buttonContainer = %ButtonContainer
@onready var cubeIntegrity = %CubeIntegrity
var waveCooldown : float


func _ready() -> void:
	EventBus.team_in_rest_changed.connect(func(count): %LabelTowerInCube.text = "Zzz : %d" % count)
	EventBus.team_in_action_changed.connect(func(count): %LabelTowerOnTerrain.text = " In action :  %d" % count)
	Game.allowed_tower_has_change.connect(addTowerButtonNodes)
	Game.cube_integrity_changed.connect(func(): cubeIntegrity.value = Game.health)
	cubeIntegrity.max_value = Game.max_health
	cubeIntegrity.value = Game.health
	Game.money_changed.connect(func(): %LabelMoney.text = "%d €" % Game.money)
	EventBus.wave_has_change.connect(onWaveChange)
	%NextWaveBtn.pressed.connect(EventBus.lauch_next_wave.emit)
	$WaveCooldown/Timer.timeout.connect(updateWaveCooldownLabel)
	%QuitLevelBtn.pressed.connect(Game.quitLevel)
	%QuitGameBtn.pressed.connect(Game.quitGame)
	$TowerInfoPanel.visible = false

	if Engine.is_editor_hint():
		var allowedTowers : Array[Tower.TYPE]
		allowedTowers.assign(Tower.TYPE.values().filter(func(v): return v))
		Game.initTowers(allowedTowers)


func _on_button_cube_pressed() -> void:
	pass # Replace with function body.


func onWaveChange(waveNumber : int, timeRemaining : float) -> void:
	%WaveNumber.text = "Wave N°%d" % waveNumber
	waveCooldown = timeRemaining
	$WaveCooldown/Timer.start()


func updateWaveCooldownLabel() -> void:
	waveCooldown -= $WaveCooldown/Timer.wait_time
	if waveCooldown > 5:
		$WaveCooldown.text = "\n\nNext wave : %3.0f" % waveCooldown
	elif waveCooldown < 0:
		$WaveCooldown/Timer.stop()
		$WaveCooldown.text = ""
	else:
		$WaveCooldown.text = "\n\nNext wave : %3.1f" % waveCooldown


func addTowerButtonNodes() -> void:
	for node in buttonContainer.get_children():
		if node.has_meta("dynamicButton"):
			node.queue_free()

	for towerType in Game.towers.keys() :
		createTowerButton(towerType)

	for i in BUTTON_QTY - (buttonContainer.get_children().size() % BUTTON_QTY):
		createTowerButton(Tower.TYPE.NONE)


func createTowerButton(towerType : Tower.TYPE) -> void:
	var btn : GuiButton = guiButton.instantiate()
	btn.set_meta("dynamicButton", true)

	if towerType:
		btn.tower = Game.towers.get(towerType)
	else:
		btn.disabled = true
	buttonContainer.add_child(btn)