TowerDefense/UI/TowerPanel.gd

extends HBoxContainer


const upgradeBtnScene : PackedScene = preload("res://UI/upgrade_button.tscn")


var tower : Tower


func _ready() -> void:
	EventBus.tower_selected.connect(onTowerSelected)


func onTowerSelected(towerType : Tower.TYPE) -> void:
	if tower:
		tower.energy_changed.disconnect(onEnergyChange)
		tower.changed.disconnect(onTowerChange)

	if towerType == Tower.TYPE.NONE:
		visible = false
		tower = null
		return

	tower = Game.towers.get(towerType)
	tower.energy_changed.connect(onEnergyChange)
	tower.changed.connect(onTowerChange)
	%UpgradeContainer.visible = false
	visible = true
	onTowerChange()


func onEnergyChange() -> void:
	%TowerEnergy.text = "%d/%d" % [ tower.energy, tower.max_energy ]


func onTowerChange() -> void:
	onEnergyChange()
	%TowerIcon.texture = tower.icone
	%TowerName.text = tower.tower_name
	%TowerDamage.text = "Dmg : %d" % tower.projectileRessource.damage
	%TowerCooldown.text = "cooldown : %.1f" % tower.action_cooldown
	# TODO Check for better UI to display it
	#%TowerBio.text = tower.bio

	if tower.builded && not %UpgradeContainer.visible:
		createTowerUpgradeButton()


func createTowerUpgradeButton() -> void:
	%UpgradeContainer.visible = true
	%UpgradeContainer.get_children().map(func(btn): btn.queue_free())
	for upgrade in tower.upgrades:
		var btn : UpgradeButton = upgradeBtnScene.instantiate()
		%UpgradeContainer.add_child(btn)
		btn.setData(tower, upgrade)