TowerDefense/Upgrades/Upgrade.gd

extends Resource
class_name Upgrade


enum SCALE_TYPE { LINEAR, EXP, LOG }
enum UPGRADE_DIRECTION { INCREASE = 1, DECREASE = -1 }


@export var icon : Texture2D = preload("res://Assets/Icones/medal2.png")
@export var text : String
@export var baseCost : int :
	set(value):
		baseCost = value
		cost = value
@export_range(0.001, 999, 0.001, "hide_slider") var value : float

@export_group("Restrictions")
@export_range(-1, 100, 1, "hide_slider") var maxLevel : int = -1 ##[param -1] for infinite leveling
@export var tierLock : Array[int]

@export_group("Upgrade Scaling")
@export var upgradeDirection : UPGRADE_DIRECTION = UPGRADE_DIRECTION.INCREASE
@export var upgradeScaleType : SCALE_TYPE = SCALE_TYPE.LINEAR
@export var costScaleType : SCALE_TYPE = SCALE_TYPE.LINEAR
@export var costModificator : float


var cost : int
var level : int = 0
var isLevelMax : bool :
	get(): return maxLevel == level && (tierLock.is_empty() || level == tierLock[Game.maxTier])


func upgrade(_subject = null) -> bool:
	return false


func upgradeProperty(subject: Variant, property: String) -> void:
	subject.set(property, getNextValue(subject.get(property), value, upgradeScaleType))


func upgradeUpgrade() -> void:
	level += 1
	Game.money -= cost
	cost = getNextValue(cost, costModificator, costScaleType)


func canUpgrade():
	return not isLevelMax && Game.money >= cost && (tierLock.is_empty() || tierLock[Game.tier] > level)


func getNextValue(oldValue, baseValue, scaleType : SCALE_TYPE):
	match scaleType:
		SCALE_TYPE.LINEAR: return oldValue + baseValue
		_:
			push_warning("Upgrade scale type not defined !")
			return oldValue